Gecko [ www.ctm-euromeuble.fr ]

Name	Size	Permission	Date
assert.awk	383 B	-rw-r--r--	2016-08-25 05:14
bits2str.awk	330 B	-rw-r--r--	2016-08-25 05:14
cliff_rand.awk	307 B	-rw-r--r--	2016-08-25 05:14
ctime.awk	234 B	-rw-r--r--	2016-08-25 05:14
ftrans.awk	315 B	-rw-r--r--	2016-08-25 05:14
getopt.awk	2.15 KB	-rw-r--r--	2016-08-25 05:14
gettime.awk	2.43 KB	-rw-r--r--	2016-08-25 05:14
grcat.c	1004 B	-rw-r--r--	2016-08-25 05:14
groupawk.in	1.73 KB	-rw-r--r--	2016-08-25 05:14
inplace.awk	1.04 KB	-rw-r--r--	2016-08-25 05:14
join.awk	378 B	-rw-r--r--	2016-08-25 05:14
libintl.awk	238 B	-rw-r--r--	2016-08-25 05:14
noassign.awk	422 B	-rw-r--r--	2016-08-25 05:14
ord.awk	937 B	-rw-r--r--	2016-08-25 05:14
passwdawk.in	1.18 KB	-rw-r--r--	2016-08-25 05:14
processarray.awk	355 B	-rw-r--r--	2016-08-25 05:14
pwcat.c	824 B	-rw-r--r--	2016-08-25 05:14
quicksort.awk	1.01 KB	-rw-r--r--	2016-08-25 05:14
readable.awk	489 B	-rw-r--r--	2016-08-25 05:14
readfile.awk	267 B	-rw-r--r--	2016-08-25 05:14
rewind.awk	404 B	-rw-r--r--	2016-08-25 05:14
round.awk	661 B	-rw-r--r--	2016-08-25 05:14
shellquote.awk	472 B	-rw-r--r--	2016-08-25 05:14
strtonum.awk	1.42 KB	-rw-r--r--	2016-08-25 05:14
walkarray.awk	214 B	-rw-r--r--	2016-08-25 05:14
zerofile.awk	424 B	-rw-r--r--	2016-08-25 05:14

Rename

# getopt.awk --- Do C library getopt(3) function in awk
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
#
# Initial version: March, 1991
# Revised: May, 1993

# External variables:
#    Optind -- index in ARGV of first nonoption argument
#    Optarg -- string value of argument to current option
#    Opterr -- if nonzero, print our own diagnostic
#    Optopt -- current option letter

# Returns:
#    -1     at end of options
#    "?"    for unrecognized option
#    <c>    a character representing the current option

# Private Data:
#    _opti  -- index in multiflag option, e.g., -abc
function getopt(argc, argv, options,    thisopt, i)
{
    if (length(options) == 0)    # no options given
        return -1

if (argv[Optind] == "--") {  # all done
        Optind++
        _opti = 0
        return -1
    } else if (argv[Optind] !~ /^-[^:[:space:]]/) {
        _opti = 0
        return -1
    }
    if (_opti == 0)
        _opti = 2
    thisopt = substr(argv[Optind], _opti, 1)
    Optopt = thisopt
    i = index(options, thisopt)
    if (i == 0) {
        if (Opterr)
            printf("%c -- invalid option\n", thisopt) > "/dev/stderr"
        if (_opti >= length(argv[Optind])) {
            Optind++
            _opti = 0
        } else
            _opti++
        return "?"
    }
    if (substr(options, i + 1, 1) == ":") {
        # get option argument
        if (length(substr(argv[Optind], _opti + 1)) > 0)
            Optarg = substr(argv[Optind], _opti + 1)
        else
            Optarg = argv[++Optind]
        _opti = 0
    } else
        Optarg = ""
    if (_opti == 0 || _opti >= length(argv[Optind])) {
        Optind++
        _opti = 0
    } else
        _opti++
    return thisopt
}
BEGIN {
    Opterr = 1    # default is to diagnose
    Optind = 1    # skip ARGV[0]

# test program
    if (_getopt_test) {
        while ((_go_c = getopt(ARGC, ARGV, "ab:cd")) != -1)
            printf("c = <%c>, Optarg = <%s>\n",
                                       _go_c, Optarg)
        printf("non-option arguments:\n")
        for (; Optind < ARGC; Optind++)
            printf("\tARGV[%d] = <%s>\n",
                                    Optind, ARGV[Optind])
    }
}